@ dEVICE pic16F628A, INTRC_OSC_NOCLKOUT 
@ device MCLR_off
@ Device WDT_off
@ Device Bod_off
'Kasim 2011
'Robotus.Net
'Uzaklik Olcumune gore cikis veren program
'Iki ultrasonik sensor mevcut, B4 ve B5 Pinlerine bagli
'B2 ve B3'den tetikleniyorlar.
'5 - 150 cm arasi okuma olursa B0 ve B1 pinleri yuksek cikis (5V) yapiliyor ve
'PortA.2'ye bagli buzzer'dan da ses cikartiliyor.
define osc 4
CMCON = 7 
mesafe1 var word 
mesafe2 var word 
genlik1 var word 
genlik2 var word 
width var word
Tetik1 VAR Portb.2 
Tetik2 VAR Portb.3 
Eko1 VAR Portb.4 
Eko2 VAR Portb.5
output porta.2
output portb.0
output portb.1
low 1
low 0
'*****************
high porta.2
pause 30 
low porta.2
'**************
basla: 
gosub ping1 
pause 35
'------
if  mesafe1 > 5 and mesafe1 < 150  then 
high portb.0
high porta.2
goto basla
endif
'------
gosub ping2 
pause 35
'------
if  mesafe2 > 5 and mesafe2 < 150  then 
high portb.1
high porta.2
goto basla
endif 
low porta.2
low portb.0
low portb.1
goto basla 
'***************** 
Ping1: 
Tetik1 = 0 
PULSOUT tetik1, 1 
PULSIN Eko1, 1, genlik1 
genlik1 = (genlik1 * 5)  
pause 1 
mesafe1 = genlik1 ** 2257 
RETURN 
'------
Ping2: 
Tetik2 = 0 
PULSOUT tetik2, 1 
PULSIN Eko2, 1, genlik2 
genlik2 = (genlik2 * 5)  
pause 1 
mesafe2 = genlik2 ** 2257 
RETURN